Скрипт телепортации

[Robinzon]

Увидал я в архиве скриптов скрипт на телепортацию, который на кольцо вешается.

Begin aa_teleport_ring
short button
short messagex2
short OnPCEquip
short PCSkipEquip
short Active

if ( OnPCEquip == 0)
   set active to 0
endif

if (OnPCEquip == 1)
   set Active to 1
endif

set PCSkipEquip to 1

if (Active == 1)
MessageBox "Вы хотите вернуться в Эндарион?" "Да" "Нет"
set messagex2 to 1
set OnPCEquip to 0
endif

if (messagex2 == 1)
Set button to GetButtonPressed

if (button == 0)
player->PositionCell, 3397, 4203, 15694, 3,  "Поместье правителя Эндариона"
set messagex2 to 0

endif

if (button == 1)
set messagex2 to 0
return

endif

endif


End

 

 

Но в этом скрипте есть 2 минуса:

1) Кольцо не надевается после использования телепортации.

2) Телепортация происходит грубо, просто очень резко.

 

Вот я глянул скрипт на амулете Аунды(Скрипт переносит игрока в ашмелех)

Begin amuletAundaeScript

short button
short messageOn
short reset
short OnPcEquip

;if ( MenuMode == 1 )
;	Return
;endif

if ( OnPCEquip == 0 )
set reset to 0
endif

if ( reset == 1 )
return
endif

if ( OnPCEquip == 1 )
if ( reset == 0 )
	if ( VampClan == 1 )
		if ( PCVampire == 1 )
			Set OnPCEquip to 0
			MessageBox "Вы хотите вернуться в Ашмелех?" "Да" "Нет"
			set messageOn to 1
		endif
	endif
endif
endif

if ( messageOn == 1)

set button to GetButtonPressed

if ( button >= 0 )
	set messageOn to 0
endif

if ( button == 0 )
	Player->PositionCell, 2816.406, 7016.756, 4306.963, 180, "Ashmelech"
	set reset to 1		
		
elseif ( button == 1 )
	set reset to 1
	return
endif
endif


End

 

Так вот, в этом скрипте есть то чего нет в первом.

 

Вот я захотел для своего колечка замуть такойже скрипт, тока без условия, типа что тока вампира амулет переносит.

Только я в скриптах полный дибил, вот и не получилось.

 

Народ помогите адаптировать скрипт, чтобы телепортацию мог использовать игрок в любом состоянии.

Но тока чтобы осталось:

1) Потемнение экана при телепортации

2) После телепортации кольцо одевается на игрока.

[Artem13]

Механизм перемещения в обоих случаях абсолютно одинаков. Так что не майся дурью. А чтобы кольцо одевалось, убери все упоминания PCSkipEquip.

[Robinzon]

Мне нужно ещё шоб экран темнел.

Сам пытался поправить скрипт Аунды-неполучилось.

Кольцо ваще не телепортировало.

Никак немогу убрать зависимость вампирскую(((

[LonWolf]

Ну вот тебе вариант "шоб экран темнел". Сразу говорю, что не тестировал, ибо на этом компе у меня даже Морровинда нет.

 

Begin LW_ring

Short OnPCEquip
Short status
Short button
float timer

if ( status == 2 )
Set timer to ( timer + GetSecondsPassed )
if ( timer > 2 )
 Player -> PositionCell 0, 0, 0, 90, "Ячейка"
 Set status to 0
 Set timer to 0
endif
endif

if ( OnPCEquip == 1 )
MessageBox "Поехали?" "Да" "Нет"
Set status to 1
Set OnPCEquip to 0
endif

if ( status == 1 )
Set button to GetButtonPressed
if ( button < 0 )
 return
elseif ( button == 0 )
 FadeIn 2
 Set status to 2
elseif ( button == 1 )
 Set status to 0
endif
endif

End